LOCAL &ppd
&ppd=OS.PPD()
&tmpDir=OS.PTD()

WinCLEAR

; --------------------------------------------------------------------------------
; common SYStem settings
PRINT   "Assigning Cores"

CD &ppd
RESet
System.RESet
SYStem.CPU ZYNQ-7000
SYStem.CONFIG CORE 1. 1.
SYStem.CONFIG SLAVE OFF
CORE.ASSIGN 1.

; set DaisyChaining Parameters of the board
; check e.g. SYStem.DETECT.ShowCHAIN
PRINT   "Setting up DaisyChain Parameters"
SYStem.CONFIG DAPIRPRE  6.
SYStem.CONFIG DAPIRPOST 0.
SYStem.CONFIG DAPDRPRE  1.
SYStem.CONFIG DAPDRPOST 0.

; trigger a soft-reset using the AHB Bus -> we loose the connection
PRINT   "Trigger Soft-Reset"
SYStem.Mode.Prepare
ON ERROR CONTinue
Data.Set EAHB:0xF8000008 %Long 0xDF0D
Data.Set EAHB:0xF8000200 %Long 0x1
WAIT 0.1s
PRINT ""
ON ERROR inherit

PRINT   "Attach and initialize"
SYStem.Mode.Attach
Break

PRINT "initializing the target"
DO "~~/demo/arm/hardware/zynq-7000/scripts/trace/ps7_init.cmm" "&ppd/../ps7_init.tcl"

PRINT "programming the FPGA design"
LOCAL &bitfile
&bitfile="&ppd/../base_zynq_wrapper.bit"
DO "~~/demo/arm/hardware/zynq-7000/scripts/zynq_bitstream" "&bitfile" 0x00100000

; --------------------------------------------------------------------------------
; initialize ONCHIP trace (ETM)
Trace.Method Onchip
ETM.TraceID 1.
ETM.Trace ON
ETM.ON

Trace.Clock 666MHz
ETM.TimeMode CycleAccurate

; Some optional settings
SETUP.Var %SpotLight
MAP.BOnchip 0x0--0xffffffff // force onchip-breakpoints
MODE.HLL

; load code
Data.LOAD.Elf "&ppd/../../../out/Aufgabe2_ps7_core0.elf"

; run to main
Go main
WAIT !STATE.RUN() 

; open some windows
DO windowSetting.cmm

; initialize RTOS support
PRINT "initializing uC/OS-II support..."
TASK.CONFIG ../ucos    ; load uC/OS-II Awareness
MENU.ReProgram ../ucos.men ; load uC/OS-II Menu
HELP.FILTER.Add rtosucos   ; add ucos awareness manual to help filter

ENDDO